!!!タイマーイベント

一定の時間間隔で関数を呼びます。
 import flash.events.*;
をソースの先頭にて指定しておく必要があります。

以下は、50msごとに現在時間を表示する例です。
 package {
    import flash.display.*;
    import flash.utils.*;           // Timerにて使用
    import flash.text.*;
    import flash.events.*;
 
    public class TimerTest extends Sprite {
        private var m_text:TextField;
        
        public function TimerTest() {
            // テキストフィールド
            m_text = new TextField();
            m_text.autoSize = "left";
            m_text.x = 0;
            m_text.y = 0;
            m_text.text = "";
            addChild(m_text);
            
            // タイマーの追加
            var timer:Timer = new Timer(50, 0);     // 50 msごと
            timer.addEventListener(TimerEvent.TIMER, onTimer);
            timer.start();
        }
        
        /**
         * タイマーイベント
         */
        private function onTimer(evt:TimerEvent):void {
            var str:String;
            var dt:Date = new Date();
            
            str = "時間 : " + String(dt.toString()); 
            m_text.text = str;
        }
    }
 }

実行すると以下のようになります。
{{flash TimerTest.swf,width=300,height=30}}

!!タイマーイベント
 var timer:Timer = new Timer(50, 0);     // 50 msごと
 timer.addEventListener(TimerEvent.TIMER, onTimer);
 timer.start();
とすることで、Timer作成時の第一引数で指定したms間隔で、
addEventListener関数の第二引数で指定した関数が呼ばれます。

呼ばれる関数の書式は
 private function onTimer(evt:TimerEvent):void {
  ...
 }
のように、第一引数にて「evt:TimerEvent」が入っているもの。