トップ 差分 一覧 ソース 検索 ヘルプ RSS ログイン

unity_shader_normal_intensity

法線マップの強弱の調整


Unity5。

_NormalIntensityに0.01〜1.0の数値を指定(0除算しないように最小範囲は0.01にしている)。

以下で、法線マップ上の法線を取得。

float3 normal  = UnpackNormal(tex2D(_NormalMap, IN.uv_NormalMap));

以下のように、Zを_NormalIntensityで割ると_NormalIntensityが0.0に近づくほど法線による凸凹はなくなる。

float3 normal2 = normalize(float3(normal.x, normal.y, normal.z / _NormalIntensity));


Shader "Custom/AOMap" {
    Properties {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        _Metallic ("Metallic", Range(0,1)) = 0.0
        _NormalIntensity ("Normal", Range(0.01,1)) = 1.0
        _NormalMap ("Normal Map", 2D) = "bump" {}
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200
        
        CGPROGRAM
        // Physically based Standard lighting model, and enable shadows on all light types
        #pragma surface surf Standard fullforwardshadows

        // Use shader model 3.0 target, to get nicer looking lighting
        #pragma target 3.0

        sampler2D _MainTex;
        sampler2D _NormalMap;

        struct Input {
            float2 uv_MainTex;
            float2 uv_NormalMap;
        };

        half _Glossiness;
        half _Metallic;
        fixed4 _Color;
        half _NormalIntensity;

        void surf (Input IN, inout SurfaceOutputStandard o) {
            fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
            o.Albedo = c.rgb;
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;

            // 法線の強さ(_NormalIntensity)を反映
            float3 normal  = UnpackNormal(tex2D(_NormalMap, IN.uv_NormalMap));
            float3 normal2 = normalize(float3(normal.x, normal.y, normal.z / _NormalIntensity));
            o.Normal = normal2;

            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}


最終更新時間:2016年10月23日 18時28分51秒